Forum Graph100

.Continue mov si,OpenExecutable ; Affiche un message
    call AfficheText
    call Getkey            ; Attend une touche

    call OldInt
    
    ;; ES pointe vers le segment de debut de l'executable

    mov dx,ds        ; Stocke ds dans dx, plus simple a suivre dans l'evolution du programme qu'un push
    
    mov ax,es
    mov ds,ax
    mov ax,0x2000
    mov es,ax
    ;; Maintenant ES pointe vers 0x2000, la zone ou on va ecrire, et DS pointe vers le debut de l'exe
    ;; On lit donc dans son entete les informations concernant sa taille
    
    mov cx,0x80
    mov ax,0
    mov di,0
    rep stosw        ; La zone remplie ici, de 256 octets, fera office de PSP

    ;; PSP
    mov word [es:    0],0x20CD    ; Appel de l'int 20h
    mov word [es:    2],0x2000    ; Adresse de chargement du programme en mémoire
    
    mov word [es:    5],0xF09A    ; Appel de l'int 21h
    mov word [es:    0x2C],0x2003 ; Place le bloc d'environnement en 2003h:0h
    
    mov word [es:    0x50],0x21CD ; Appel de l'int 21h
    mov word [es:    0x51],0xCB

    push ds
    mov ax,0
    mov ds,ax
    mov ax,[ds:    0x84]    ; Vecteur int21h
    mov [es:9],ax
    mov ax,[ds:    0x86]
    mov [es:7],ax
    mov ax,[ds:    0x88]    ; Vecteur int22h
    mov [es:0x0A],ax
    mov ax,[ds:    0x8A]
    mov [es:0x0C],ax
    mov ax,[ds:    0x8C]    ; Vecteur int23h
    mov [es:0x0E],ax
    mov ax,[ds:    0x8E]
    mov [es:0x10],ax
    mov ax,[ds:    0x90]    ; Vecteur int24h
    mov [es:0x12],ax
    mov ax,[ds:    0x92]
    mov [es:0x14],ax    
    pop ds

    mov word [es:    0x40],6    ; N° de version du dos

    ;; Copie de la ligne de commande et du bloc d'environnement
    push di            ; On en aura besoin après
    push ds

    mov ds,dx
    mov si,command        ; SI pointe sur la ligne de commande
    mov cl,[ds:si]        ; CL contient la taille de la ligne de commande
    mov [es:0x80],cl
    add byte [es:0x80],2    ; La chaine est plus longue car on rajoute le $:
    mov ch,0        ; CX egalement
    mov di,0x83        ; Fait pointer DI vers la zone a ecrire dans le PSP
    rep movsb        ; Copie la ligne de commande et sa taille en 0x80 du PSP

    mov bl,[CrtDrive]    ; BL contient la lettre courante de lecteur
    mov [es:0x81],bl
    mov word [es:0x82],0x5C3A ; :
    

    mov si,envir        ; SI pointe sur le bloc d'environnement
    mov cl,[ds:si]        ; CL contient la taille du bloc
    mov ch,0        ; CX egalement
    inc si            ; SI pointe sur le debut du bloc
    mov di,0x30        ; Fait pointer DI vers la zone a ecrire dans le PSP
    rep movsb        ; Copie la ligne de commande et sa taille en 0x80 du PSP

    pop ds
    pop di            ; On recupère DI

    push ds
    
    push word [ds:    0x4]    ; On lit le mot contenant la taille prise en § par le fichier. 1§ = 512 octets
    mov bx,ds
    mov ax,[ds:    0x8]    ; Taille de l'entete en secteurs de 16 octets
    add bx,ax
    mov ds,bx        ; ds pointe vers le debut du binaire
    
    shr ax,5        ; ax contient la taille de l'entete en paragraphes
    dec ax            ; ax contient la taille de l'entete en paragraphes -1
    mov bx,ax
    pop ax            ; ax contient la taille du fichier en §
    sub ax,bx        ; ax contient la taille du binaire en §
    xor si,si

    ;; On va copier le binaire en memoire après le PSP. On va le copier 512 octets par 512, et incrementé à chaque fois les pointeurs de segments
Copie:    
    push si        ; Si doit valoir 0, pour que [ds:si] soit correcte    
    push di            ; On aura besoin de ces deux valeurs a chaque passage de la boucle
    
    mov cx,0x200
    rep movsw
    
    mov bx,es
    add bx,0x20
    mov es,bx        ; es = es + 20
    
    mov bx,ds
    add bx,0x20
    mov ds,bx        ; ds = ds + 20

    pop di
    pop si
    
    dec ax
    jnz Copie

    pop ds
    mov cx,[ds:    0x6]
    cmp cx,0
    jz Execution
    
    mov si,[ds:    0x18]
    
Relocation:
    mov di,[ds:    si]
    mov ax,[ds:    si+2]
    add ax,0x2010
    mov es,ax
    add word [es:    di],0x2010
    add si,4
    loop Relocation
    
Execution:    
    mov ax,0x3000
    mov ss,ax
    
    push word 0xFFFE    ; SP d'execution
    
    mov ax,[ds:    0x16]
    add ax,0x2010
    push ax            ; CS d'execution
    
    push word [ds:    0x14]    ; IP d'execution
    
    mov ax,0x2000
    mov ds,ax
    mov es,ax
    xor ax,ax
    xor bx,bx
    xor cx,cx
    xor dx,dx
    retf            ; Charge depuis la pile IP,CS et PS